Vous pouvez également le faire dans Outlook via VBA. Office 2010 ne vous permet plus de supprimer via la plupart de ces solutions.
Word, PowerPoint, et Excel vous permettent d'utiliser cette solution facile .
Outlook nécessite plus de travail car il utilise à la fois les Explorateurs et les Inspecteurs, qui dans différents contextes les deux ont cette barre de commande activée. La solution est donc en deux parties.
La première partie consiste à configurer WithEvents pour gérer la création de chaque nouvel Inspecteur. En général, il s'agit de chaque fois que vous OUVREZ un message/événement, et ils sont créés/détruits à chaque fois. Ainsi, même si vous touchez chaque inspecteur actuel, la barre de commande ne sera pas désactivée dans vos nouveaux inspecteurs.
Mettez ce qui suit dans ThisOutlookSession dans votre éditeur VBA (Alt+F11). Chaque nouvel inspecteur (et explorateur aussi, bien que je n'ai pas encore créé d'explorateur) aura sa barre de commande désactivée.
Public WithEvents colInspectors As Outlook.Inspectors
Public WithEvents objInspector As Outlook.Inspector
Public WithEvents colExplorers As Outlook.Explorers
Public WithEvents objExplorer As Outlook.Explorer
Public Sub Application_Startup()
Init_colExplorersEvent
Init_colInspectorsEvent
End Sub
Private Sub Init_colExplorersEvent()
Set colExplorers = Outlook.Explorers
End Sub
Private Sub Init_colInspectorsEvent()
'Initialize the inspectors events handler
Set colInspectors = Outlook.Inspectors
End Sub
Private Sub colInspectors_NewInspector(ByVal NewInspector As Inspector)
Debug.Print "new inspector"
NewInspector.commandbars("Research").Enabled = False
'This is the code that creates a new inspector with events activated
Set objInspector = NewInspector
End Sub
Private Sub colExplorers_NewExplorer(ByVal NewExplorer As Explorer)
'I don't believe this is required for explorers as I do not think Outlook
'ever creates additional explorers... but who knows
Debug.Print "new explorer"
NewExplorer.commandbars("Research").Enabled = False
'This is the code that creates a new inspector with events activated
Set objExplorer = NewExplorer
End Sub
Cependant, cela ne fera disparaître le menu que de certaines des vues dans Outlook. Vous devrez toujours exécuter la macro suivante pour le supprimer de tous les explorateurs. Pour autant que je puisse le dire, elle est persistante lorsque vous fermez/réouvrez Outlook :
Private Sub removeOutlookResearchBar()
'remove from main Outlook explorer
Dim mExp As Explorer
For Each mExp In Outlook.Explorers
mExp.commandbars("Research").Enabled = False
Next mExp
End Sub
