Comment créer un raccourci à l'aide d'un script batch ?

Vous pouvez y parvenir sans outils externes en créant un VBScript temporaire :

@echo off

set SCRIPT="%TEMP%\%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%.vbs"

echo Set oWS = WScript.CreateObject("WScript.Shell") >> %SCRIPT%
echo sLinkFile = "%USERPROFILE%\Desktop\myshortcut.lnk" >> %SCRIPT%
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> %SCRIPT%
echo oLink.TargetPath = "D:\myfile.extension" >> %SCRIPT%
echo oLink.Save >> %SCRIPT%

cscript /nologo %SCRIPT%
del %SCRIPT%

(Idée tirée de ici .)

Cela créera myshortcut.lnk sur le bureau, en pointant sur D:\myfile.extension.

Vous pouvez fournir des propriétés supplémentaires avant d'enregistrer le lien en modifiant les valeurs suivantes :

oLink.Arguments
oLink.Description
oLink.HotKey
oLink.IconLocation
oLink.WindowStyle
oLink.WorkingDirectory

Consultez Comment créer un raccourci sur le bureau avec l'hôte de script Windows pour voir quelques exemples.

@echo off
echo [InternetShortcut] >> "%AllUsersProfile%\desktop\NOTEPAD.url"
echo URL="C:\WINDOWS\NOTEPAD.EXE" >> "%AllUsersProfile%\desktop\NOTEPAD.url"
echo IconFile=C:\WINDOWS\system32\SHELL32.dll >> "%AllUsersProfile%\desktop\NOTEPAD.url"
echo IconIndex=20 >> "%AllUsersProfile%\desktop\NOTEPAD.url"

Ce code crée un raccourci dans le dossier “All Users” du bureau appelé NOTEPAD.url qui pointe vers l'application NotePad, et attribue également une icône à partir du fichier SHELL32.dll. Changez le chemin et le nom du fichier pour votre D:/ location et exename. Et assurez-vous que votre nom de fichier .url reste le même sur toutes les lignes de code.

il y a une commande externe shortcut.exe qui peut le faire de cette façon :

shortcut /a:c /f:"c:\users\me\desktop\myshortcut.lnk" /t:"c:\program files\skype\skype.exe"

qui peut créer un raccourci de skype sur votre bureau

c'est un programme téléchargeable gratuitement, mais je ne trouve pas son lien, donc je vais essayer de le télécharger et de poster le lien

ici : shortcut.exe par Marty List